Mit einer Formel Zellenwerte festlegen

Inhalt

1 Zellenformel
2 Referenzsyntaxen für Spaltenzelle
3 Beispiele
4 Formeln über Zeilen oder Spalten erweitern
- 4.1 Teil des Blattes erweitern
- 4.2 Teil der Mappe erweitern
5 Blitzvorschau
6 Beschränkungen
7 Mit Formelleiste
8 Anwenderparameterzeile Formel
9 Verwandte Systemvariablen
10 Weiteres

Zellenformeln

Origin unterstützt die Zellenformel in beiden Datenzellen und benutzerdefinierte Spaltenbeschriftungszellen im Arbeitsblatt seit Origin 2018.

Beginnen Sie die Formel mit dem Zeichen = in der Zelle.
Verwenden Sie Origins Labtalk-Standardfunktionen.
Greifen Sie auf Datenzellen, Beschriftungszellen, Spalten, benannte Bereiche, Metadaten, Variablen, Konstanten etc. in der Berechnung zu.
Ziehen Sie an der Formel, um sie auf andere Zellen zu erweitern.
Die Formel wird automatisch angepasst, wenn eine Spalte/Zeile eingefügt oder gelöscht oder wenn sie an eine andere Stelle kopiert wird.

Um Formelzellen auf den ersten Blick zu unterscheiden, wählen Sie Ansicht: Formel/Verknüpfte Zellen hervorheben, so dass die Zellen mit einer anderen Hintergrundfarbe hervorgehoben werden.

Referenzsyntaxen für Spaltenzelle

Die einfache Zellennotation (SCN) muss in der Arbeitsmappe aktiviert sein, so dass Anwender mit einer Excel-ähnlichen Notation auf die Spalte und Zelle verweisen können.

Spalte	Zelle	Bereich	Beschriftungszeile
A - Spalte A This - aktuelle Spalte	A1, A[1] - Spalte A, Zeile 1 A0 - Spalte A, letzte Zeile A[i] - Spalte A, aktuelle Zeile Verwenden Sie This[1], This[i] für die Zeilen in der aktuellen Spalte.	A1:A10, A[1:10] - Spalte A, Zeile 1-10 A1:B0 - Spalte A Zeile 1 bis Spalte B letzte Zeile A[i:i+2] - Spalte A, aktuelle Zeile bis 2 Zeilen nach ihr This[i-2:i-1] - aktuelle Spalte, zwei Zeilen vor der aktuellen Zeile	A[C]$ - Spalte A, Zeichenkette der Kommentarzelle A[EID]$ - Spalte A, Zeichenkette der benutzerdefinierten Parameter EID A[D1] - Spalte A, Wert des 1. benutzerdefinierten Parameters Verwenden Sie This[C]$, This[EID]$, This[D1] für die Beschriftungszelle in der aktuellen Spalte.

Fügen Sie sheetname!, sheetindex!, [bookname]sheetname! oder [bookname]sheetindex! vor der Spaltenzellenreferenz hinzu, falls die Daten sich in einem anderen Blatt oder einer anderen Mappe befinden.
Fügen Sie $ nach der Spaltenzellenreferenz für die Zeichenkette hinzu, z. B. A1$, A$.
Für den Unterbereich muss : sich innerhalb der [ ] befinden. A[1]:A[10] & A[1]:D[10] werden nicht unterstützt. Verwenden Sie A[1:10] für die gleiche Spalte oder A1:D10 für unterschiedliche Spalten.
Fügen Sie $ vor dem Spalten- oder Zeilenteil für die absolute Referenz hinzu. Siehe den Abschnitt Formeln über Zeilen oder Spalten erweitern unten.
Verwenden Sie ==, um die Bereichszeichenkette und den Ausdruck, der die Bereichszeichenkette enthält, zu erzeugen, falls das aktuelle A1 den Mappennamen enthält. Z. B. verweist =="["+A1$+"]"+"1!C1" auf die Zelle C1 des 1. Blatts in einer festgelegten Mappe in A1. =="1000+["+A1$+"]"+"1!C1*0.3" ist ein Ausdruck, der auf so einer C1-Zelle basiert.

Beispiele

Die Beispiele zeigen nur die relative Referenz. Fügen Sie $ vor dem Spalten- oder Zeilenteil für die absolute Referenz hinzu. Siehe den Abschnitt Formeln über Zeilen oder Spalten erweitern unten.

Origin	Excel	Beschreibung
=B1 - C1	=B1-C1	Unterschied zwischen B1 und C1.
=B - B0	N/A	Differenz zwischen der aktuellen Spalte B und der letzten Zeile von Spalte B.
=B1-mean(B)	=B1-average(B:B)	Differenz zwischen B1 und dem Durchschnitt von Spalte B
=mean(This)	N/A	Durchschnitt der aktuellen Spalte
=B1$ + C1$	=B1 & C1	Zusammengefasste Zeichenketten in B1 und C1.
=IF(A1<98.6, A1-98.6, NA())	=IF(A1<98.6, A1-98.6, NA())	Wenn A1 <= 98,6, wird A1-98,6 ausgegeben. Andernfalls wird ein fehlender Wert ausgegeben (siehe LabTalk-Utility-Funktion Na()).
*=col(A)[D1]A1**	N/A	Der Wert der Spalte A Anwenderparameter 1 multipliziert mit dem Wert in Spalte A, Zeile 1.
=lookup(This[element]$, [book1]1!1, [book1]1!2)$	N/A	Sucht den Wert der Spaltenbeschriftung Element in einer Spalte und gibt den Wert einer anderen Spalte mit dem gleichen Index des gefundenen Elements aus. (Siehe das Video im Abschnitt Anwenderparameterzeile.)
*=page.v1B1**	N/A	Der Wert der Systemvariable v1 (mit Seite gespeichert) multipliziert mit dem Wert in Spalte B, Zeile 1.
=A1-page.info.File1.Info.FileDate	N/A	A1 - minus die Info des Dateidatums der importierten Datei, die auf der Seite gespeichert ist, angenommen A1 ist ebenfalls ein Datum.
=date(A1, "dd.MM.yyyy HH:mm:ss.##")	-- ^†	Julianischer Tageswert von A1 im festgelegten Format Datum-Zeit. Beachten Sie die Differenzen im Verhalten von Origin und Excel.
=total(A[1:3])	=SUM(A1:A3)	Summe von A1 bis A3.
=Total(wcol(j-1)[1:3])	N/A	Summe der Zeilen 1 bis 3 gleich links von der aktuellen Spalte.
=total(Sheet2!A1:J10)+total(Sheet1!A1:J10)	=SUM(Sheet2!A1:J10)+SUM(Sheet1!A1:J10)	Summe von A1 bis J10 auf beiden Blättern, sheet1 und sheet2.
=Sheet2!B1 - Sheet3!B1	=Sheet2!B1 - Sheet3!B1	Differenz von B1 auf zwei Blättern
=[Book2]Sheet1!A1 - [Book3]Sheet1!A1	=[Book2]Sheet1!A1 - [Book3]Sheet1!A1	Differenz zwischen A1 in verschiedenen Mappen
=[Book2]Sheet1!col(A)[1] - [Book3]Sheet1!col(A)[1]	N/A	Differenz zwischen A1 auf verschiedenen Mappen mit der alten Syntax col(name)[row]
=[Book1]Sheet1!col(A)[1] + StartTime	N/A	Fügt den Wert "StartTime" des benannten Bereichs zu dem Wert von A1 im Blatt sheet1 der Mappe Book1 hinzu.
=text(mean(B1:B10),".2")+" ± "+text(stddev(B1:B10),".4")	=(TEXT(AVERAGE(B1:B10),"0.00") & " ± " & TEXT(STDEV(B1:B10),"0.0000"))	Berechnet den Mittelwert und die Standardabweichung eines Bereichs, rundet dann auf eine festgelegte Anzahl von Dezimalstellen und wandelt schließlich in Text um. Fasst zusammen und fügt dabei die Zeichenkette " ± " (z. B. 0,56 ± 0,2740) ein.

Formeln über Zeilen oder Spalten erweitern

Markieren Sie die Zelle mit der Formel und bewegen Sie die Maus über ihre Ecke rechts unten. Wenn der Cursor sich in ein + verwandelt, ziehen Sie ihn zm Erweitern entweder nach unten, quer oder diagonal.

Die Spalten- und Zeilenreferenz in Formeln wird auf relative Weise erweitert:

beim vertikalen Ziehen, nur der Zeilenteil ändert sich

beim horizontalen Ziehen, nur der Spaltenteil ändert sich

beim diagonalen Ziehen, beide Teile ändern sich

Platzieren Sie ein $ vor den Teil, um eine absolute Referenz zu erstellen. Um z. B. den Zeilenteil festzulegen, fügen Sie ein $ vor dem Zeilenteil hinzu, B$1. Um beides, Spalte und Zelle, festzulegen, platzieren Sie ein $-Zeichen vor dem Spalten- und dem Zeilenteil, z. B. $B$1.

Doppelklick auf + wird auch unterstützt. Im Fall eines Datenbereichs wird bis zum unteren Ende der Spalte automatisch gefüllt. Im Fall eines Beschriftungsbereichs wird bis zum unteren Ende der Spalte automatisch gefüllt.

Drücken Sie für Zeilenreferenzen in eckigen Klammern, z. B. sum(A)[1] oder A[1], beim Ziehen die Strg-Taste, um die relative Referenz beizubehalten.

Teil des Blattes erweitern

Origin unterstützt relative Blattreferenzen beim Erweitern der Formel nicht. Wie fügt man z. B. die B1-Zelle von allen Sensor-Blättern in ein neues Blatt ein? Anwender können =Sensor01!B$1 oder =1!B$1 eingeben und dann an der Formel ziehen, um =Sensor02!B$1, =Sensor03!B$1, ..., oder =2!B$1, =3!B$1, .... zu erhalten.

Workarounds:

Variable i bedeutet Zeilenindex. Durch Hinzufügen von $(i) vor ! kann sie als Blattindex verwendet werden.
Nehmen Sie den Blattindex oder den Namen in einer Spalte und verwenden Sie die Syntax ==, um ihn mit dem Spalten- und Zeilenteil zusammenzufassen und eine vollständige Zellenreferenz zu bilden.

Im obigen Beispiel verwandelt A1$ den Inhalt von A1 in eine Zeichenkette. "!B1" ist eine literale Zeichenkette. ==A1$+"!B1" fasst sie in =Sensor01!B1 zusammen, das auf B1 des Blatts Sensor01 verweist.

Hinweis

Die Blattzeichenketten müssen auf der gleichen Seite sein, auf der Sie Ihre sich automatisch anpassenden Blattreferenzen erstellt haben.
==A1$+"!B1+10" erzeugt einen Ausdruck Sensor01!B1+10.
Wenn die Zeichenkette des Blatts Sonderzeichen enthält, wie "-", dann setzen Sie den Blattnamen in doppelte Anführungszeichen: ==char(34)$+A1$+char(34)$+"!B1+10".

Teil der Mappe erweitern

Mit der Syntax == können auch Mappe, Blatt, Spalten- und Zeilenteil zusammengefasst werden, um eine vollständige Zellenreferenz zu erstellen.

Im folgenden Beispiel werden die Mappenkurznamen in Spalte A eingefügt und gezeigt, wie die Zellenformel verwendet wird, um Spalte B mit den B2-Werten in jeder Mappe zu füllen.

Geben Sie in Zelle B1 =="["+A1$+"]"+"Sheet1!B2" ein. Ziehen Sie an der unteren rechten Ecke der Zelle B1 nach unten bis zur 12. Zeile, so dass B2 in 12 Mappen gefüllt wird.

Cell formula relative book double quote.png

Blitzvorschau

Wenn die Spalte(n) auf der linken Seite ein deutliches Muster zeigt und Sie das erwartete Ergebnis in der ersten Zelle der Zielspalte eingeben, entdeckt Origin automatisch das Muster, errät, wie Sie extrahieren, kombinieren oder die Zeichenkette bzw. Zahl rekonstruieren möchten, und schlägt mögliche Funktionen und Formeln in einer Vorschau vor. Sie können die Spalte mit Folgendem füllen:

Einfache Werte (Strg + Shift + E): Statische Ergebnisse, die bei Änderung der Quelldaten festgelegt bleiben.
Erzeugte Formeln (Strg + Shift + Enter): Dynamische Ergebnisse, die automatisch bei Änderung der Referenzspalten aktualisiert werden.

Mit der „Blitzvorschau" können Sie:

Den gewünschten Teil der Spalte extrahieren

Sie können zum Beispiel den Vornamen und Nachnamen aus einer Spalte teilen oder die gewünschte Zeichenkette aus dem Dateipfad extrahieren.

Spalten kombinieren

Einige Arten der Neuformatierung durchführen

Beschränkungen

Hier sind einige bekannte Probleme beim Verwenden der Zellenformel.

Beim Importieren einer MS Excel-Datei werden Ihre Excel-Formeln nicht mit importiert. Es werden nur berechnete Werte importiert. Siehe Arbeiten mit Microsoft Excel.
Zellformeln werden nicht in den Spaltenbeschriftungszeilen wie wie Langname, Einheiten, Kommentare etc. unterstützt. Sie werden nur in den benutzerdefinierten Parameterzeilen unterstützt.
Die Variablen i und j werden für den Zeilen- und Spaltenindex in Origin verwendet (siehe Systemvariablen), das heißt, A[i], col(A)[i], wcol(j)[1] und wcol(j)[i] werden noch in den Zellformeln unterstützt, funktionieren in einigen Fällen aber nicht gut in Kombination mit dem Erweitern der Formel etc.
wcol(j) verweist auf die j-te Spalte, kann jedoch unzuverlässig sein, da der Wert von J unbestimmt ist außer in einer Formel mit mehreren Spalten. Sie funktioniert z. B. eventuell nicht, wenn sie in einem Funktionsargument verwendet wird, um eine Zeichenkette auszugeben. Versuchen Sie es stattdessen mit This, wenn Sie können.
Das Erweitern einer Zellenformel über viele Zeilen und Spalten kann die Systemressourcen belasten und Origin dazu bringen abzustürzen. In vielen Fällen können Sie die gleiche Aufgabe einfacher mit der Funktion Spaltenwerte festlegen erledigen.

Formelleiste

Die Ansicht: Formelleiste wurde in Origin 2021 eingeführt und stellt eine Excel-ähnliche Leiste dar, in die Sie Zellen- oder Spaltenformeln/-ausdrücke eingeben können. Während es nicht notwendig ist, die Formelleiste zu verwenden, um Zellenausdrücke einzugeben, hat sie ihre Vorteile:

einfachere Methode für Eingabe und Anzeige von langen Ausdrücken, die die Zellenbreite überschreiten.
Suchfunktionen über die Schaltfläche , die den Dialog Funktionen suchen und einfügen öffnet.
interaktive Bereichsauswahl im Ausdruck durch Klicken auf die Spaltenüberschrift oder Zelle oder durch Aufziehen eines Bereichs. Hinweis: Nicht unterstützt für unterschiedliche Mappe.
Definieren eines benannten Bereichs durch Auswahl des Bereichs und dann Eingabe eines Namens auf der linken Seite der Formelleiste.
Navigieren zu einem benannten Bereich durch Auswahl des Bereichs der linken Seite der Formelleiste.

Hinweis: Ändern Sie die Schriftgröße, indem Sie den Wert der Systemvariable @FBFS (Standardwert ist "130") ändern.

Anwenderparameter Zeilenformel

Seit Origin 2019 können Sie mit der rechten Maustaste auf die Überschriften der Spaltenbeschriftungszeilen klicken, Anwenderparameter hinzufügen und für die gesamte Zeile eine Formel definieren. Dies ist praktisch beim Berechnen von wesentlichen Statistiken (z. B. Mittelwert, Standardabweichung) für jede Spalte mit Zahlen in einem Arbeitsblatt.

Die Spaltenformel verwendet den Platzhalter "This" als Referenz auf jede Spalte im Arbeitsblatt (siehe nächster Abschnitt).

Wenn eine Zeilenformel erstellt wurde, können Sie den Namen und die Formel durch einen Rechtsklick auf die Überschrift der Anwenderparameterzeile und Auswahl der Option Bearbeiten im Kontextmenü bearbeiten. Sie können die Zellformeln einzeln bearbeiten, indem Sie doppelt direkt in die Zelle einer Anwenderparameterzeile klicken.

Sie können eine mit einer Formel definierte Anwenderparameterzeile in mehrere Arbeitsblätter über die Schaltfläche der Minisymbolleiste Anwenderparameter anwenden auf kopieren. Weitere Einzelheiten finden Sie hier.